Windows 7: Login automatico all’avvio del sistema (Batch)

| |

registry-tutorial1-regeditI più attenti potrebbero far caso al titolo di questo articolo. Si tratta di qualcosa di già detto e pubblicato solo qualche mese fa: gioxx.org/2015/03/09/windows-7-login-automatico-allavvio-del-sistema:

(…) utile quando si tratta di dover far partire un PC non presidiato e che non debba costringervi ogni volta ad alzarvi dalla scrivania per andare chissà dove solo per un CTRL + ALT + CANC seguito dalla solita procedura di inserimento password e colpo di invio.

Dato che quella modifica di registro mi è tornata utile qualche giorno fa, ho deciso di tradurre il tutto in un file batch che chiede direttamente a video le informazioni. Ovviamente, potendo migliorare un attimo il codice, il batch sarà capace di richiedervi i diritti amministrativi (necessari per modificare il registro di sistema da prompt dei comandi, nda) e vi guiderà passo-passo, proponendovi anche il nome della macchina sulla quale lancerete lo script, perché potrebbe tornare utile da utilizzare al posto del dominio, nel caso in cui il PC sul quale abilitare l’auto-logon non sia in un dominio Microsoft.

Tutto il resto rimane ovviamente identico, è stato solo automatizzato in base ai parametri che voi stessi riporterete a video:

@echo off
REM Windows 7 Auto-Logon Enabler
REM http://gioxx.org/tag/logon-automatico/
REM GSolone 2014 (ult.mod. 24112015)

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Richiedo utente amministratore...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params = %*:"=""
    echo UAC.ShellExecute "cmd.exe", "/c %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    cls
    echo Microsoft Windows 7 Auto-Logon Enabler
    echo.
:RICHIESTADATI
    echo Specificare ora i dati da inserire a registro per eseguire l'auto-logon.
    echo ATTENZIONE: in caso di errore rilanciare lo script per modificare i valori precedentemente memorizzati.
    echo.
    echo Nel caso dovesse servire, questo e' il nome della macchina locale: %COMPUTERNAME%
    echo (se la macchina non e' in dominio, il campo DOMINIO dovra' riportare il nome della macchina locale!)
    echo.
    SET /P DOMINIO=Dominio (esempio: CONTOSO)        : 
    SET /P UTENTE=Nome utente (esempio: mario.rossi): 
    SET /P PASSWDUTENTE=Password (esempio: Pa$$w0rd)      : 
:AGGIUNTADATI
    echo.
    echo Inserisco i dati specificati nel registro di sistema ...
    REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /V AutoAdminLogon /T REG_SZ /D 1 /F
    REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /V DefaultDomainName /T REG_SZ /D %DOMINIO% /F
    REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /V DefaultUserName /T REG_SZ /D %UTENTE% /F
    REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /V DefaultPassword /T REG_SZ /D %PASSWDUTENTE% /F
    echo.
    echo Operazione terminata.
    echo Premere un tasto per riavviare la macchina e verificare il funzionamento dell'Auto-Logon.
    pause > NUL
    shutdown -r -t 0

:--------------------------------------

:END

Potete trovare il batch, già pronto per il download e l’utilizzo, sul mio spazio box: bit.ly/autologon-enabler.

Commenti e suggerimenti sono sempre ben accetti ;-)

Buon lavoro!

Correzioni, suggerimenti? Lascia un commento nell'apposita area qui di seguito o contattami privatamente.
Ti è piaciuto l'articolo? Offrimi un caffè! ☕ :-)

L'articolo potrebbe non essere aggiornato

Questo post è stato scritto più di 5 mesi fa, potrebbe non essere aggiornato. Per qualsiasi dubbio ti invito a lasciare un commento per chiedere ulteriori informazioni! :-)

Condividi l'articolo con i tuoi contatti:
Subscribe
Notify of
guest

This site uses Akismet to reduce spam. Learn how your comment data is processed.

0 Commenti
Inline Feedbacks
View all comments